Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00123_utility handlers.ls

Text File | 2004-07-11 | 3.8 KB | 167 lines

-- TOOLS

---------------------------------------------------------
-- CURSOR --
-- set up the cursor of a group of sprites

-- what cursor can be:
-- "hand"
-- "nohand" this is a hand with an x through it
-- "pointer"
-- "closedHand"

global gTotalSprites

on initHandCursor whatCursor, spriteList
  -- set up the drag cursor thingie
  case (whatCursor) of
    "hand":
      set cursor = the number of member "hand"
      set mask = the number of member "hand mask"
    "pointer":
      set cursor = the number of member "pointer"
      set mask = the number of member "pointer mask"
    "noHand":
      set cursor = the number of member "noHand"
      set mask = the number of member "noHand mask"
    "closedHand":
      set cursor = the number of member "closedHand"
      set mask = the number of member "closedHand mask"
    otherwise return
  end case

  -- now set the cursor
  if voidP(spriteList) then
    -- director 6 has 120 cells
    set maxCells = gTotalSprites


    -- default to all the sprites
    put "I am setting a cursor on all the sprites...initCursor() in frame: " & the frame

    repeat with x = 1 to maxCells
      if the cursor of sprite x <> [cursor, mask] then
        set the cursor of sprite x = [cursor, mask]
      end if
    end repeat

  else

    repeat with x in spriteList
      if the cursor of sprite x <> [cursor, mask] then
        set the cursor of sprite x = [cursor, mask]
      end if
    end repeat
  end if
end


-- this will clear the hand cursor from the listed sprites
on clearHandCursor spriteList
  -- clear the cursor
  if voidP(spriteList) then
    -- director 6 has 120 cells
    set maxCells = gTotalSprites

    -- default to all the sprites
    put "I am clearing the cursor on all the sprites...clearCursor() in frame: " & the frame

    repeat with x = 1 to maxCells
      set the cursor of sprite x = 0
    end repeat

  else
    repeat with x in spriteList
      set the cursor of sprite x = 0
    end repeat
  end if
end


---------------------------------------------------------
-- EFFECT HANDLERS --

-- changes the ink for a blink effect
-- this is NOT asynchronous
on blinkSprite targetSprite, blinkInk, repetitions, howLong
  set oldInk = the ink of sprite targetSprite

  -- get into the loop
  repeat with x = 1 to repetitions
    set the ink of sprite targetSprite = blinkInk
    updateStage

    wait(howLong)

    set the ink of sprite targetSprite = oldInk
    updateStage

    wait(howLong)
  end repeat
end

---------------------------------------------------------
-- MISC --
on wait howLong
  set endTime = the timer + howLong

  repeat while the timer < endTime
    updateStage
  end repeat
end

-- eliminating redraw buggies...

on forceFullStageRedraw
  tell the stage
    set the stageColor = the stageColor
    updateStage
  end tell
end

on forceFullRedraw
  forceFullStageRedraw()

  if the windowlist <> [] then
    -- walk through director's windowList
    repeat with x in the windowList
      set thisWindow = x
      tell thisWindow
        set the stageColor = the stageColor
        updateStage
      end tell
    end repeat

  end if
end


-------------------------------------------------------------------------------------
-- puppet controlling routine
--
--on puppetsOff whatPuppets
--
--  if voidP(whatPuppets) then
--    -- default to all sprite channels
--    repeat with x = 1 to 48
--      puppetSprite x, FAÃSE
--    end repeat
--
--    return -1
--
--  else
--    -- otherwise we have a list
--    if ilk(whatPuppets, #list) then
--      repeat with x in whatPuppets
--        puppetSprite x, FALSE
--      end repeat
--
--      return 0
--    end if
--  end if
--
--end
--
--------------------------------------------------------------------------------------
--